INFO Online

[Roberio Severo]

Pessoal,

como faço para bloquear apenas uma cÉlula do excel

[JValq]

Bom dia,

Para que o bloqueio de uma ou mais células funcione, é necessário PROTEGER a planilha.

Por padrão, todas as células estão bloqueadas.

Para proteger uma célula, apenas, você deve:

Selecionar a planilha inteira (CTRL + T);
Menu Formatar/Células (CTRL + 1);
Aba "Proteçao", deixe a caixa de seleção "Bloqueadas" em branco;
Selecione a célula que quer bloquear e repita o processo, deixando marcada a caixa "Bloqueadas"
Menu Ferramentas/Proteger, para proteger a planilha.

A partir daí, todas as células serão editáveis, exceto a que você bloqueou.

Caso queira fazer isso via macro, o código abaixo bloqueia a célula A1:

Código: Selecionar tudo

Sub ProtegerCelula()
    'Desprotege a planilha (se estiver protegida)
    ActiveSheet.Unprotect "SUA SENHA"
        'Desbloqueia TODAS as células da planilha
        ActiveSheet.Cells.Locked = False
        'Bloqueia a célula A1
        [A1].Locked = True
    'Protege, novamente, a planilha com senha "SUA SENHA"
    ActiveSheet.Protect "SUA SENHA"
End Sub

Um abraço

[Roberio Severo]

BLZ!!

Mais eu tinha visto em uma planiha onde o usuario bloqueou uma celular. Ex.: celula estava bloqueada quando o usuario tentava alterar a celula aparecia a tela de desproteger pedido a senha de liberação.

[JValq]

Boa tarde,


É exatamente isso que acontece.

Se você tentar alterar uma célula bloqueada, vai aparecer a mensagem dizendo que a célula está bloqueada e que é necessário desproteger a planilha.

O que ocorre é que você pode proteger COM ou SEM senha.


Um abraço

[Mauro Coutinho]

Roberio, você está falando sobre o outro tipo de proteção que seria o recurso "Permitir que os usuarios editem intervalos..".

Para isso voce vai no Menu / Ferramentas / Proteger / Permitir que os usuarios editem intervalos..., na tela que abrir clique em Novo e siga os passos, depois de definido proteja a planilha e tente alterar a celula que usou o recurso acima e será exibida a solicitação da senha, mas observe que esse recurso só tem efeito se proteger a planilha, e tambem depois de digitado a senha a celula continuara desbloqueada.
Leia mais sobre esse recurso no link abaixo:
http://www.scribd.com/doc/14499724/Jame ... s-do-Excel

Abaixo uma rotina que simplifica sem precisar navegar pelo Menu, com o Titulo, Celula e Senha definidos, é só alterar conforme sua necessidade.

'Defini uma Celula e protege com senha

Código: Selecionar tudo

Sub ProtegeUmaCelulaComSenha()

Dim ws As Worksheet
Set ws = Application.ActiveSheet

'Desprotege a planilha
    ws.Unprotect
   
    ' Estabelecer o Range que pode ser editado
    ' na Planilha protegida com solicitação da senha.
    'Foi definido a Celula  A1 com o Titulo e Senha
    ws.Protection.AllowEditRanges.Add _
        Title:="MinhaCelula", _
        Range:=Range("A1"), _
        Password:="senha"

    MsgBox "A Celula A1 está protegida e pode ser alterada apos digitar a senha"

'Protege a planilha
ws.Protect
End Sub

'Deleta o Titulo da celula - somente o titulo o conteudo não altera.

Código: Selecionar tudo

Sub DeletaTitulo()
Dim ws As Worksheet
Dim myCel As AllowEditRange

Set ws = Application.ActiveSheet
    ws.Unprotect

'Deleta todas as celulas definidas
    For Each myCel In ActiveSheet.Protection.AllowEditRanges
        myCel.Delete
    Next myCel
   
    ws.Protect
End Sub

'Apagar ou Alterar a Senha:

Código: Selecionar tudo

Sub ApagaOuAlteraSenha()
Dim ws As Worksheet

Set ws = Application.ActiveSheet
   
    ws.Unprotect

    ' Apaga somente a Senha.
    ws.Protection.AllowEditRanges.Item(1).ChangePassword _
        Password:=""

'OU
    ' Define outra Senha.
    'ws.Protection.AllowEditRanges.Item(1).ChangePassword _
        Password:="roberio"

    MsgBox "A Senha para essa celula foi alterada."

ws.Protect
End Sub

abraços

[Mauro Coutinho]

Mais alguns links interessantes sopbre o recurso "Permitir que usuários editem intervalos"

A opção Permitir que usuários editem intervalos :
http://www.ricardohorta.net/ms_excel_xp ... ha_01.html

Descrição das opções ajudam a proteger suas planilhas no Excel 2003 e no Excel 2002
http://support.microsoft.com/kb/826923/pt-br

[]s